読者です 読者をやめる 読者になる 読者になる

pixyzehn blog

iPhone App, Mac App, Programming, Web service, Tool, Evernote, etc

zsh の初期設定がめんどくさい人のためのoh-my-zshを入れてみました

Tips

f:id:inagex:20140421110158p:plain


簡単にzshがいい感じになりました。


oh-my-zshを知ったのはrebuild.fmがきっかけです。(2014/4/20放送の回)


こちらです→http://rebuild.fm/41/


詳しくはこちら↓


Rebuild.fmをカレンダーに登録してパソコンサンデーを有意義に過ごしてみる - 理系大学生のwebメモRebuild.fmをカレンダーに登録してパソコンサンデーを有意義に過ごしてみる - 理系大学生のwebメモはてなブックマーク - Rebuild.fmをカレンダーに登録してパソコンサンデーを有意義に過ごしてみる - 理系大学生のwebメモ



それまでは、.zshrcでちょっとカスタマイズしていましたが、oh-my-zshのほうが使いやすそうだったので使ってみました。


f:id:inagex:20140421110505p:plain


またテーマがたくさんあるところもいいと思いました。


こちらがテーマ一覧。

https://github.com/robbyrussell/oh-my-zsh/wiki/Themes


まずoh-my-zshを使うにあたってhomebrewのzshを使用していなかったのでそちらの設定をします。


こちらを参考にしてhomebrewのzshを使うように設定しました。


http://iori-o.github.io/blog/2013/04/17/install-zsh-for-mac/


そしたらhomebrewでzshをインストールします。

brew install zsh


次にoh-my-zshをインストールします。

curl -L https://github.com/robbyrussell/oh-my-zsh/raw/master/tools/install.sh | sh


ただしこれを実行すると、~/.zshrcが上書きされていたので、元々自分の.zshrcを使っている人はbackupをとっておいたほうがいような気がします。


僕は~/dotfile/.zshrcのファイルを~/.zshrcにシンボリックリンクをはっていたので、~/.zshrcは上書きされても大丈夫でした。


oh-my-zshをアンインストールしたら元の~/.zshrcに戻りました。(シンボリックリンクはっておいたからかも)


ちなみにアンインストールは

uninstall_oh_my_zsh


というコマンドのみでできます。


今回はプラグインを使わずにテーマだけ変えました。


プラグインのことはこちらを参考にしてみてください。


http://qiita.com/udzura/items/0d08d71d809bfd8c5981


ではテーマの変更をしていきます。


一通りテーマをみてこれだ!というのが「agnoster」というやつでした。


f:id:inagex:20140421111502p:plain


rebuild.fmを聞くに雷とか聞こえたから@miyagawaさんも使っている(いた?)模様です。


先ほどのインストールが終わると~/.zshrcというファイルが生成されているのでそちらを編集していきます。

ZSH_THEME="agnoster"


ZSH_THEMEという項目があるので、そちらをagnosterに変更します。デフォルトではrobbyrussellになっています。


そして以下を追加します。
https://gist.github.com/agnoster/3712874からの引用です。

# vim:ft=zsh ts=2 sw=2 sts=2
#
# agnoster's Theme - https://gist.github.com/3712874
# A Powerline-inspired theme for ZSH
#
# # README
#
# In order for this theme to render correctly, you will need a
# [Powerline-patched font](https://gist.github.com/1595572).
#
# In addition, I recommend the
# [Solarized theme](https://github.com/altercation/solarized/) and, if you're
# using it on Mac OS X, [iTerm 2](http://www.iterm2.com/) over Terminal.app -
# it has significantly better color fidelity.
#
# # Goals
#
# The aim of this theme is to only show you *relevant* information. Like most
# prompts, it will only show git information when in a git working directory.
# However, it goes a step further: everything from the current user and
# hostname to whether the last call exited with an error to whether background
# jobs are running in this shell will all be displayed automatically when
# appropriate.

### Segment drawing
# A few utility functions to make it easy and re-usable to draw segmented prompts

CURRENT_BG='NONE'
SEGMENT_SEPARATOR='⮀'

# Begin a segment
# Takes two arguments, background and foreground. Both can be omitted,
# rendering default background/foreground.
prompt_segment() {
  local bg fg
  [[ -n $1 ]] && bg="%K{$1}" || bg="%k"
  [[ -n $2 ]] && fg="%F{$2}" || fg="%f"
  if [[ $CURRENT_BG != 'NONE' && $1 != $CURRENT_BG ]]; then
    echo -n " %{$bg%F{$CURRENT_BG}%}$SEGMENT_SEPARATOR%{$fg%} "
  else
    echo -n "%{$bg%}%{$fg%} "
  fi
  CURRENT_BG=$1
  [[ -n $3 ]] && echo -n $3
}

# End the prompt, closing any open segments
prompt_end() {
  if [[ -n $CURRENT_BG ]]; then
    echo -n " %{%k%F{$CURRENT_BG}%}$SEGMENT_SEPARATOR"
  else
    echo -n "%{%k%}"
  fi
  echo -n "%{%f%}"
  CURRENT_BG=''
}

### Prompt components
# Each component will draw itself, and hide itself if no information needs to be shown

# Context: user@hostname (who am I and where am I)
prompt_context() {
  local user=`whoami`

  if [[ "$user" != "$DEFAULT_USER" || -n "$SSH_CLIENT" ]]; then
    prompt_segment black default "%(!.%{%F{yellow}%}.)$user@%m"
  fi
}

# Git: branch/detached head, dirty status
prompt_git() {
  local ref dirty
  if $(git rev-parse --is-inside-work-tree >/dev/null 2>&1); then
    ZSH_THEME_GIT_PROMPT_DIRTY='±'
    dirty=$(parse_git_dirty)
    ref=$(git symbolic-ref HEAD 2> /dev/null) || ref="➦ $(git show-ref --head -s --abbrev |head -n1 2> /dev/null)"
    if [[ -n $dirty ]]; then
      prompt_segment yellow black
    else
      prompt_segment green black
    fi
    echo -n "${ref/refs\/heads\//⭠ }$dirty"
  fi
}

# Dir: current working directory
prompt_dir() {
  prompt_segment blue black '%~'
}

# Status:
# - was there an error
# - am I root
# - are there background jobs?
prompt_status() {
  local symbols
  symbols=()
  [[ $RETVAL -ne 0 ]] && symbols+="%{%F{red}%}✘"
  [[ $UID -eq 0 ]] && symbols+="%{%F{yellow}%}⚡"
  [[ $(jobs -l | wc -l) -gt 0 ]] && symbols+="%{%F{cyan}%}⚙"

  [[ -n "$symbols" ]] && prompt_segment black default "$symbols"
}

## Main prompt
build_prompt() {
  RETVAL=$?
  prompt_status
  prompt_context
  prompt_dir
  prompt_git
  prompt_end
}

PROMPT='%{%f%b%k%}$(build_prompt) '


またagnosterはPowerline-patched fontを入れる必要があります。


こちらからフォントをインストールします。


https://gist.github.com/qrush/1595572


やっぱりRictyがいいとかの場合はこちらを参考に


vim-airlineを入れてみてfontにパッチをあててみた - 理系大学生のwebメモvim-airlineを入れてみてfontにパッチをあててみた - 理系大学生のwebメモはてなブックマーク - vim-airlineを入れてみてfontにパッチをあててみた - 理系大学生のwebメモ


こちらをiterm2のフォントに設定します。(iterm2を使っているとしました)


iterm2で

echo "⮀ ± ⭠ ➦ ✔ ✘ ⚡"


を実行して


f:id:inagex:20140421112433p:plain


となればフォント設定完了です。


また名前の箇所を変更したかったので以下の箇所を変更しました。

# Context: user@hostname (who am I and where am I)
prompt_context() {
  local user=`whoami`
 
  if [[ "$user" != "$DEFAULT_USER" || -n "$SSH_CLIENT" ]]; then
    prompt_segment black default "%(!.%{%F{yellow}%}.)$user@%m"
  fi
}


変更後

### Prompt components
# Each component will draw itself, and hide itself if no information needs to be shown

# Context: user@hostname (who am I and where am I)
prompt_context() {
  local user=`whoami`
    prompt_segment black default "%(!.%{%F{yellow}%}.)pixyzehn"
}


こんな感じで簡単にzshが見新しくなりました。


f:id:inagex:20140421112920p:plain


参考サイト

http://qiita.com/ryoppy@github/items/df7ae39f45892c3c96fc


https://github.com/robbyrussell/oh-my-zsh/wiki/Themes